3D 프린팅 메이커 캠프 (중2)
제공 코드11차시, LED 깜빡이기 (setup과 loop)
| 언어 | Arduino C++ |
|---|---|
| 설명 | 내장 LED 점멸 예제. 학생은 블록으로 같은 동작을 만들고, 교사는 블록과 코드를 나란히 보여 준다. |
// Blink the on-board LED (pin 13)
void setup() {
pinMode(13, OUTPUT); // runs once
}
void loop() { // runs forever
digitalWrite(13, HIGH);
delay(1000); // try 200
digitalWrite(13, LOW);
delay(1000);
}3D 프린팅 메이커 캠프 (중2)
제공 코드11차시, 능동부저와 택트 스위치 알람
| 언어 | Arduino C++ |
|---|---|
| 설명 | 버튼 알람 예제. 30초 뒤 알람이 울리고 버튼을 누르면 멈춘다. |
const int buzzerPin = 8;
const int buttonPin = 7;
bool alarmOn = false;
const int waitTime = 30; // 대기 시간 30초
void setup() {
pinMode(buzzerPin, OUTPUT);
pinMode(buttonPin, INPUT_PULLUP);
Serial.begin(9600); // 시리얼 통신 시작
for (int i = waitTime; i > 0; i--) {
Serial.print("Waiting for ");
Serial.print(i);
Serial.println(" seconds...");
delay(1000); // 1초 대기
}
Serial.println("Alarm activated!");
alarmOn = true; // 알람 활성화
}
void loop() {
// 알람이 활성화되어 있고 스위치가 눌리지 않았을 때 알람이 울립니다.
if (alarmOn && digitalRead(buttonPin) == HIGH) {
tone(buzzerPin, 1000); // 1kHz 주파수로 부저를 울립니다.
}
else { // 알람이 활성화되어 있지 않거나 스위치가 눌렸을 때
noTone(buzzerPin); // 부저를 멈춥니다.
alarmOn = false; // 알람 비활성화
}
}3D 프린팅 메이커 캠프 (중2)
제공 코드12차시, 조도센서 자동 가로등
| 언어 | Arduino C++ |
|---|---|
| 설명 | 키트 예제 I(조도센서를 활용한 자동 가로등). THRESHOLD는 활동지 6에서 잰 값으로 바꾼다. 모듈에 따라 어두울수록 값이 커지거나 작아지므로 부등호 방향을 먼저 확인한다. |
const int CDS_PIN = A0;
const int LED_PIN = 9;
int THRESHOLD = 500; // set from your measurements
void setup() {
pinMode(LED_PIN, OUTPUT);
Serial.begin(9600);
}
void loop() {
int light = analogRead(CDS_PIN); // 0~1023
Serial.println(light);
if (light > THRESHOLD) { // dark (check direction for your module)
digitalWrite(LED_PIN, HIGH);
} else {
digitalWrite(LED_PIN, LOW);
}
delay(200);
}3D 프린팅 메이커 캠프 (중2)
제공 코드12차시, 초음파 주차 보조 (거리별 LED와 부저)
| 언어 | Arduino C++ |
|---|---|
| 설명 | 키트 예제 F(초음파 센서를 활용한 주차 보조). 가까우면 빨강+부저, 중간이면 노랑, 멀면 초록. 거리 기준(10cm, 30cm)은 작품에 맞게 바꾼다. |
const int TRIG = 2, ECHO = 3;
const int RED = 9, YELLOW = 10, GREEN = 11, BUZZER = 8;
long readCm() {
digitalWrite(TRIG, LOW); delayMicroseconds(2);
digitalWrite(TRIG, HIGH); delayMicroseconds(10);
digitalWrite(TRIG, LOW);
long us = pulseIn(ECHO, HIGH, 30000); // timeout 30 ms
return us / 58; // round trip -> cm
}
void setup() {
pinMode(TRIG, OUTPUT); pinMode(ECHO, INPUT);
pinMode(RED, OUTPUT); pinMode(YELLOW, OUTPUT);
pinMode(GREEN, OUTPUT); pinMode(BUZZER, OUTPUT);
Serial.begin(9600);
}
void loop() {
long cm = readCm();
Serial.println(cm);
digitalWrite(RED, cm > 0 && cm < 10);
digitalWrite(YELLOW, cm >= 10 && cm < 30);
digitalWrite(GREEN, cm >= 30 || cm == 0);
digitalWrite(BUZZER, cm > 0 && cm < 10);
delay(100);
}3D 프린팅 메이커 캠프 (중2)
제공 코드12~14차시, 자동문: 20cm 안에 물체가 있으면 서보 180°
| 언어 | Arduino C++ |
|---|---|
| 설명 | 기획안 예시('20cm 이내 물체가 있으면 1초 뒤 서보모터 180도, 없으면 2초 뒤 0도')를 코드로 옮긴 것입니다. SG-90 동작 범위는 0~180°. |
#include <Servo.h>
const int TRIG = 2, ECHO = 3;
Servo door;
long readCm() {
digitalWrite(TRIG, LOW); delayMicroseconds(2);
digitalWrite(TRIG, HIGH); delayMicroseconds(10);
digitalWrite(TRIG, LOW);
return pulseIn(ECHO, HIGH, 30000) / 58;
}
void setup() {
pinMode(TRIG, OUTPUT); pinMode(ECHO, INPUT);
door.attach(9);
door.write(0);
Serial.begin(9600); // check behavior without watching the motor
}
void loop() {
long cm = readCm();
Serial.println(cm);
if (cm > 0 && cm <= 20) {
delay(1000);
door.write(180); // open
} else {
delay(2000);
door.write(0); // close
}
}3D 프린팅 메이커 캠프 (중2)
제공 코드11차시, 수동부저 멜로디 (짧게 줄인 판)
| 언어 | Arduino C++ |
|---|---|
| 설명 | 멜로디 예제(음 이름 #define 표와 tone 반복)를 첫 소절만 남겨 줄였다. 음 배열만 바꿔 학교 종소리 등으로 바꿔 보게 한다. |
#define NOTE_C7 2093
#define NOTE_E7 2637
#define NOTE_G7 3136
#define NOTE_G6 1568
int melody[] = { NOTE_E7, NOTE_E7, 0, NOTE_E7, 0, NOTE_C7, NOTE_E7, 0, NOTE_G7, 0, 0, 0, NOTE_G6 };
int durations[] = { 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12 };
void setup() {
pinMode(8, OUTPUT);
}
void loop() {
for (int i = 0; i < sizeof(melody) / sizeof(int); i++) {
int d = 1000 / durations[i];
tone(8, melody[i], d);
delay(d * 1.30);
noTone(8);
}
delay(5000);
}